Menus

[Dawn M]

First, the necessities:

Progress 9.1 C (but using ADM not ADM2), GUI, NT

I am looking to create a start menu for my users. I want to make this look like the menu of a previous system that I'm trying to write out. That menu is table driven. It looks like this...

1. Option 6. Option
2. Option 7. Option
3. Option 8. Option
4. Option 9. Option
5. Option 10. Option

It has two columns that appear to be browsers. A user can right-arrow/left arrow between the columns. Down-arrow/up-arrow to move through the options.

I have attemped to use two browsers side-by-side, but can't get the highlight bar on the "non-focused" browser to go away. (I couldn't get CLEAR-SELECTION to work.) But, try as I might, I can't seem to duplicate it. (And I've been a Progress geek for 12+ years!)

Any ideas would be greatly appreciated.

 

[laa]

Is something like this what you are trying to do?

DEFINE VARIABLE SELECT-1 AS CHARACTER
VIEW-AS SELECTION-LIST SINGLE
LIST-ITEMS "Option 1","Option 2","Option 3","Option 4","Option 5"
SIZE 11 BY 3.6 NO-UNDO.

DEFINE VARIABLE SELECT-2 AS CHARACTER
VIEW-AS SELECTION-LIST SINGLE
LIST-ITEMS "Option 6","Option 7","Option 8","Option 9","Option 10"
SIZE 11 BY 3.6 NO-UNDO.

DEFINE FRAME fMenu
SELECT-1 AT ROW 1 COL 11 NO-LABEL
SELECT-2 AT ROW 1 COL 21 NO-LABEL
WITH 1 DOWN NO-BOX KEEP-TAB-ORDER OVERLAY
SIDE-LABELS NO-UNDERLINE THREE-D
AT COL 1 ROW 1
SIZE 80 BY 17.

ON CURSOR-RIGHT OF SELECT-1 DO:
SELECT-2:SCREEN-VALUE = SELECT-2:ENTRY(SELECT-1:LOOKUP(SELECT-1:SCREEN-VALUE)).
SELECT-1:SCREEN-VALUE = "":U.
APPLY "ENTRY":U TO SELECT-2.
END.

ON CURSOR-LEFT OF SELECT-2 DO:
SELECT-1:SCREEN-VALUE = SELECT-1:ENTRY(SELECT-2:LOOKUP(SELECT-2:SCREEN-VALUE)).
SELECT-2:SCREEN-VALUE = "":U.
APPLY "ENTRY":U TO SELECT-1.
END.

DISPLAY SELECT-1 SELECT-2
WITH FRAME fMenu.
ENABLE SELECT-1 SELECT-2
WITH FRAME fMenu.

SELECT-1:SCREEN-VALUE IN FRAME fMenu = SELECT-1:ENTRY(1).
SELECT-2:SCREEN-VALUE = "":U.

WAIT-FOR WINDOW-CLOSE OF CURRENT-WINDOW FOCUS SELECT-1.



Hope this helps.

Anne.

 

[bendaluz2]

Sounds like a listview would be perfect for what you want.

 

[Dawn M]

Yes, it does sound like it would work. I'll give it a shot. Sometimes, you need someone else to "think outside the box" when you can't.

Thanks laa!